대략 이런식

예전에 매크로 제작했을 때, 썼던 코드를 떼온겁니다

위에 진형 부분을 변경하면 쫄/영웅 버튼 위치가 진형에 맞게 변경됩니다

=============================================================

#SingleInstance Force

Gui, Font, c1E90FF S25 W600 Bold Underline
Gui, Add, Text, x20 y25 w230 h70 , 진형 설정
Gui, Font

Gui, Add, DropDownList, x20 y100 w100 h100 gC_JakTF vV_JakTF, 기본 진형||밸런스 진형|공격 진형|보호 진형

Gui, Font, Bold
Gui, Add, Button, x130 y100 w20 h20 gH_JakTF, ?
Gui, Font

Gui, Add, Button, x202 y200 w60 h50 vV_JakTF_H1 gC_JakTF_H, 영웅
Gui, Add, Button, x202 y300 w60 h50 vV_JakTF_H2 gC_JakTF_H, 영웅
Gui, Add, Button, x102 y160 w60 h50 vV_JakTF_H3 gC_JakTF_H, 쫄
Gui, Add, Button, x102 y250 w60 h50 vV_JakTF_H4 gC_JakTF_H, 쫄
Gui, Add, Button, x102 y340 w60 h50 vV_JakTF_H5 gC_JakTF_H, 쫄

Gui, Font, Underline Bold
Gui, Add, Button, x92 y450 w80 h30 gGuiClose +BackgroundTrans, 적용
Gui, Font

Gui, Font, Underline Bold
Gui, Add, Button, x192 y450 w80 h30 gGuiClose, 취소
Gui, Font

Gui, Color, 0xADD8E6


Gui, Show, x545 y129 h500 w363, 진형 설정 (모험작)
Return

GuiClose:
ExitApp



C_JakTF()
{
    GuiControlGet, v_JakTF,, V_JakTF

    If (v_JakTF == "기본 진형")
    {
        arrX := [202, 202, 102, 102, 102]
        arrY := [200, 300, 160, 250, 340]
    }
    Else If (v_JakTF == "밸런스 진형")
    {
        arrX := [202, 202, 202, 102, 102]
        arrY := [160, 250, 340, 200, 300]
    }
    Else If (v_JakTF == "공격 진형")
    {
        arrX := [202, 102, 102, 102, 102]
        arrY := [250, 160, 220, 280, 340]
    }
    Else If (v_JakTF == "보호 진형")
    {
        arrX := [202, 202, 202, 202, 102]
        arrY := [160, 220, 280, 340, 250]
    }


    Loop, 5
    {
        vecX := arrX[A_Index]
        vecY := arrY[A_Index]

        GuiControl, Move, V_JakTF_H%A_Index%, x%vecX% y%vecY%
        GuiControl, +Redraw, V_JakTF_H%A_Index%
    }
}


C_JakTF_H()
{
    GuiControlGet, vTempJakTF_H,, %A_GuiControl%
   
    If (vTempJakTF_H == "쫄")
        GuiControl,,%A_GuiControl%, 영웅
    Else If (vTempJakTF_H == "영웅")
        GuiControl,,%A_GuiControl%, 쫄
}


H_JakTF()
{
    MsgBox, 64, 도움말,
    (
- 모험작을 할 때 사용할 진형을 선택합니다
   
- 진형을 따로 설정하지 않을 경우에는 기본 설정으로
  진형이 '기본 진형'으로 설정됩니다

- 쫄은 말그대로 모험작 대상 영웅을 의미하고,
  영웅은 해당 지역을 클리어하기 위해 필요한 영웅을
  의미합니다

- 각, 지역마다 진형을 다르게 설정할수도 있고, 똑같이
  설정할수도 있습니다
 
- 영웅 위치 순서는 오른쪽 상단부터 왼쪽 하단까지 차례
  대로입니다
 
- 영웅/쫄은 해당 영웅 위치의 버튼을 눌러 변경시킬 수
  있습니다
    )
}