OnMessage(0x100, "GUI_KeyDown", 2) ;// This when the GUI is initialized.
이렇게 선언하고
GUI_KeyDown(wParam, lParam, nMsg, hWnd)
{
pipa := ComObjQuery(WEB, "{00000117-0000-0000-C000-000000000046}")
VarSetCapacity(kMsg, 48), NumPut(A_GuiY, NumPut(A_GuiX
, NumPut(A_EventInfo, NumPut(lParam, NumPut(wParam
, NumPut(nMsg, NumPut(hWnd, kMsg)))), "uint"), "int"), "int")
Loop 2
{
r := DllCall(NumGet(NumGet(1*pipa)+5*A_PtrSize), "ptr", pipa, "ptr", &kMsg)
}
;// Loop to work around an odd tabbing issue (it's as if there
;// is a non-existent element at the end of the tab order).[/color]
until wParam != 9 || WEB.Document.activeElement != ""
ObjRelease(pipa)
if r = 0 ;// S_OK: the message was translated to an accelerator.
return 0
}
아래의 함수를 추가해놨습니다. 근데 GUI에서 Send,{Enter} 작업이 필요한데 Enter 작업이 먹히질않네요...
어떻게 써야 Enter 이 먹힐까요? (ActiveX 에 먹혀야합니다.)
0
-0
블로그에도 문의해주셨는데 코드가 길어서 여기에 답변해드릴게요
검색창에 아무렇게나 치고 F1 눌러보세요
#NoEnv
#NoTrayIcon
#SingleInstance Off
#KeyHistory 0
ListLines Off
SetBatchLines, -1
Init := new Browser()
return
F1::
Init.OnMessage("13", "1835009", "256", Init.hWnd)
return
class Browser
{
static URL := "https://duckduckgo.com"
__New()
{
global
Gui, New, +Resize +hwndhMain
this.hMain := hMain
Gui, Add, ActiveX, x0 y0 w500 h500 hwndhEmbed vWB, Shell.Explorer
this.hEmbed := hEmbed
WB.silent := true, WB.Navigate(this.URL)
this.Bound := []
this.Bound.OnMessage := this.OnMessage.Bind(this)
WinEvents.Register(this.hMain, this)
for each, Msg in [0x100, 0x201, 0x202, 0x204]
OnMessage(Msg, this.Bound.OnMessage)
Gui,Show, % " w" A_ScreenWidth*0.7 " h" A_ScreenHeight*0.7 , 브라우저
}
GuiSize()
{
DllCall("MoveWindow", "Ptr", this.hEmbed, "Int", 0, "Int", 0, "Int", A_GuiWidth, "Int", A_GuiHeight, "Int", 1)
}
GuiClose()
{
for each, Msg in [0x100, 0x201, 0x202, 0x204]
OnMessage(Msg, this.Bound.OnMessage, 0)
this.Delete("Bound"), WinEvents.Unregister(this.hMain)
Gui, Destroy
ExitApp
}
OnMessage(wParam, lParam, Msg, hWnd)
{
static fields := "hWnd,Msg,wParam,lParam,A_EventInfo,A_GuiX,A_GuiY"
global WB
this.hWnd := hWnd
if (Msg == 0x100)
{
pipa := ComObjQuery(WB.document, "{00000117-0000-0000-C000-000000000046}")
VarSetCapacity(Msgs, 48)
Loop Parse, fields, `, ;`
NumPut(%A_LoopField%, Msgs, (A_Index-1)*A_PtrSize)
TranslateAccelerator := NumGet(NumGet(1*pipa)+5*A_PtrSize)
Loop 2
r := DllCall(TranslateAccelerator, "Ptr",pipa, "Ptr",&Msgs)
until wParam != 9 || WB.document.activeElement != ""
ObjRelease(pipa)
if r = 0
return 0
}
}
}
class WinEvents
{
static Table := {}
Register(hWnd, Class, Prefix="Gui")
{
Gui, +LabelWinEvents.
this.Table[hWnd] := {Class: Class, Prefix: Prefix}
}
Unregister(hWnd)
{
this.Table.Delete(hWnd)
}
Dispatch(hWnd, Type)
{
Info := this.Table[hWnd]
return Info.Class[Info.Prefix . Type].Call(Info.Class)
}
Close()
{
return WinEvents.Dispatch(this, "Close")
}
Size()
{
return WinEvents.Dispatch(this, "Size")
}
}